// TODOs
//   - Screen saver?
public class WarmCold extends PApplet{

  static public void main(String args[]) {
    //PApplet.main(new String[] { "", "--present", "WarmCold" });
    PApplet.main(new String[] { "WarmCold" });
  }  

float[][] colorArr;
int w = 600;
int h = 400;
//int w = screen.width;
//int h = screen.height;
int nx = 15; // 20
int sqSize = floor(w/float(nx));
int ny = floor(h/float(sqSize));
int shiftX = round( (w-sqSize*nx) /2. );
int shiftY = round( (h-sqSize*ny) /2. );

Point[] coldPoints;
int nColdPointsMax = 8;
Point[] warmPoints;
int nWarmPointsMax = 7;

float hueMinDiff = 0.06;
float hueColdLow = 0.4;
float hueColdHigh = 0.71; //0.71
float hueWarmLow = 0.0;
float hueWarmHigh = hueColdLow;
float huePointDiff = 0.0002;
float hueFluctuation = 0.0005;

float diffConstH = 0.05;
float diffConstV = 0.005;
float coldPointCoupling = 0.03;
float warmPointCoupling = 0.02;

float moveWarmProb = 0.001;
float moveColdProb = 0.001;

void setup() 
{
  size(w, h);
  colorMode(HSB, 1.0);
  background(color(1.,0.,0.));
  frameRate(20);
  colorArr = new float[nx][ny];
  colorArr = randomize();
  coldPoints = new Point[nColdPointsMax];
  initializeColdPoints();
  warmPoints = new Point[nWarmPointsMax];
  initializeWarmPoints();
  noStroke();
}

void draw()
{
  colorArr = diffuse(colorArr);
  //diffuse2();
  for (int i=0; i<nx; i++) {
    for(int j=0; j<ny; j++) {
      fill( hueMap( colorArr[i][j] ) , 1.0, brMap(colorArr[i][j]));
      rect(i*sqSize+shiftX, j*sqSize+shiftY, sqSize, sqSize);
    }
  }
  //drawDebugPoints();
}

// Strech that there is more warm - less green - flat blue again
float hueMap(float in) {
  float out;
  float crossX = hueWarmHigh;
  float crossY = hueWarmHigh-0.15;
  float crossX2 = crossX + 0.1;
  float crossY2 = crossY + 0.3;
  if (in < crossX) {
    out = map(in, 0., crossX, 0., crossY);
  } else if (in < crossX2) {
    out = map(in, crossX, crossX2, crossY, crossY2);
  } else {
    out = map(in, crossX2, 1., crossY2, 1.);
  }
  return out;
}

// make colder colors darker
float brMap(float in) {
  float out;
  float crossX = hueWarmHigh;
  float crossY = hueWarmHigh-0.15;
  float crossX2 = crossX + 0.1;
  float crossY2 = crossY + 0.25;
  if (in < crossX) {
    out = map(in, 0., crossX, 0., crossY);
  } else if (in < crossX2) {
    out = map(in, crossX, crossX2, crossY, crossY2);
  } else {
    out = map(in, crossX2, 1., crossY2, 1.);
  }
  return 1.-out;
}

// mark the warm and cold points ...
void drawDebugPoints() {
  for (int i=0; i<nColdPointsMax; i++) {
    fill(0.,1.0,1);
    ellipse((coldPoints[i].x +0.5) * sqSize +shiftX, (coldPoints[i].y+0.5)*sqSize +shiftY, sqSize/4, sqSize/4);
  } 
  for (int i=0; i<nWarmPointsMax; i++) {
    fill(0.71,1.0,1);
    ellipse((warmPoints[i].x +0.5) * sqSize +shiftX, (warmPoints[i].y+0.5)*sqSize +shiftY, sqSize/4, sqSize/4);
  }
}

// do initial randomness
float[][] randomize() {
  float[][] tmpArr = new float[nx][ny];
  for (int j=0; j<ny; j++) {
    tmpArr[0][j] = random(hueColdLow,hueColdHigh);
    for(int i=1; i<nx; i++) {
      float newHue = tmpArr[i-1][j] + random(-hueMinDiff, hueMinDiff);
      newHue = min(newHue, hueColdHigh);
      newHue = max(newHue, hueColdLow);
      tmpArr[i][j] = newHue;
    }
  }
  return tmpArr;
}

// main work: diffuse the heat and cold
float[][] diffuse(float[][] colorArr) {
  float[][] tmpArr = new float[nx][ny];
  float diff;
  tmpArr = colorArr;

  // Keep cold and warm points
  tmpArr = setColdPoints(tmpArr);
  tmpArr = setWarmPoints(tmpArr);

  // diffuse
  for (int j=0; j<ny-1; j++) {
    for(int i=0; i<nx-1; i++) {
      //tmpArr[i][j] = colorArr[i][j];
      // N
      diff = (colorArr[i][j] - colorArr[i][j+1]) * diffConstV;
      tmpArr[i][j] -= diff;
      tmpArr[i][j+1] += diff;
      // E
      diff = (colorArr[i][j] - colorArr[i+1][j]) * diffConstH;
      tmpArr[i][j] -= diff;
      tmpArr[i+1][j] += diff;
    }
  }
  // special case lower right corner not yet covered
  //i = nx-1, j = ny-2
  int i = nx-1;
  int j = ny-2;
  // N
  diff = (colorArr[i][j] - colorArr[i][j+1]) * diffConstV;
  tmpArr[i][j] -= diff;
  tmpArr[i][j+1] += diff;
  //i = nx-2, j = ny-1
  i = nx-2;
  j = ny-1;
  // E
  diff = (colorArr[i][j] - colorArr[i+1][j]) * diffConstH;
  tmpArr[i][j] -= diff;
  tmpArr[i+1][j] += diff;

  tmpArr = fluctuate(tmpArr);
  tmpArr = normalize(tmpArr);

  return tmpArr;
}

float[][] normalize(float[][] tmpArr) {
  for (int j=1; j<ny; j++) {
    for(int i=1; i<nx; i++) {
      tmpArr[i][j] = max(hueWarmLow, tmpArr[i][j]);
      tmpArr[i][j] = min(hueColdHigh, tmpArr[i][j]);
    }
  }
  return tmpArr;
}

// add some small randomness to make it more lively
float[][] fluctuate(float[][] tmpArr) {
  for (int j=1; j<ny; j++) {
    for(int i=1; i<nx; i++) {
      tmpArr[i][j] += random(-hueFluctuation, hueFluctuation);
    }
  }
  return tmpArr;
}

float[][] setColdPoints(float[][] tmpArr) {
  for (int i=0; i<nColdPointsMax; i++) {
    float diff;
    if (tmpArr[coldPoints[i].x][coldPoints[i].y] >= coldPoints[i].hue) {
      diff = sqrt((tmpArr[coldPoints[i].x][coldPoints[i].y] -coldPoints[i].hue))*coldPointCoupling;
    } else {
      diff = -sqrt(-(tmpArr[coldPoints[i].x][coldPoints[i].y] -coldPoints[i].hue))*coldPointCoupling;
    }
    tmpArr[coldPoints[i].x][coldPoints[i].y] -= diff;
    // move
    if (random(1.) < moveColdProb) {
      if (round(random(1.)) > 0) {
        if (round(random(1.)) > 0) {
          // N
          coldPoints[i].y += 1;
          if (coldPoints[i].y > ny-1) coldPoints[i].y = 0;
        } else {
          // S
          coldPoints[i].y -= 1;
          if (coldPoints[i].y < 0) coldPoints[i].y = ny-1;
        }
      } else {
        if (round(random(1.)) > 0) {
          // W - dont use warm space
          coldPoints[i].x -= 1;
          if (coldPoints[i].x < 1) coldPoints[i].x = nx-2;
        } else {
          // E - dont use warm space
          coldPoints[i].x += 1;
          if (coldPoints[i].x > nx-2) coldPoints[i].x = 1;
        }
      }        
      // change hue
      float hue = random(hueColdHigh-huePointDiff, hueColdHigh);
      coldPoints[i].hue = hue;
    }
  }
  return tmpArr;
}

float[][] setWarmPoints(float[][] tmpArr) {
  for (int i=0; i<nWarmPointsMax; i++) {
    //tmpArr[warmPoints[i].x][warmPoints[i].y] = warmPoints[i].hue;
    float diff;
    if (tmpArr[warmPoints[i].x][warmPoints[i].y] >= warmPoints[i].hue) {
      diff = sqrt(sqrt((tmpArr[warmPoints[i].x][warmPoints[i].y] -warmPoints[i].hue)))*warmPointCoupling;
    } else {
      diff = -sqrt(sqrt(-(tmpArr[warmPoints[i].x][warmPoints[i].y] -warmPoints[i].hue)))*warmPointCoupling;
    }      
    //float diff = (tmpArr[warmPoints[i].x][warmPoints[i].y] -warmPoints[i].hue)*warmPointCoupling;
    tmpArr[warmPoints[i].x][warmPoints[i].y] -= diff;
    // move up or down
    if (random(1.) < moveWarmProb) {
      if (round(random(1.)) > 0) {
        warmPoints[i].y += 1;
        if (warmPoints[i].y > ny-1) warmPoints[i].y = 0;
      } else {
        warmPoints[i].y -= 1;
        if (warmPoints[i].y < 0) warmPoints[i].y = ny-1;
      }
      // change hue
      float hue = random(hueWarmLow, hueWarmLow+huePointDiff);
      warmPoints[i].hue = hue;
    }
    // move to other side 
    if (random(1.) < moveWarmProb/2.) {
      if (warmPoints[i].x == 0) {
        warmPoints[i].x = nx-1;
      } else {
        warmPoints[i].x = 0;
      }
      // change hue
      float hue = random(hueWarmLow, hueWarmLow+huePointDiff);
      warmPoints[i].hue = hue;
    }
  }
  return tmpArr;
}

void initializeColdPoints() {
  for (int i=0; i<nColdPointsMax; i++) {
    int x = floor( random(nx-2) ) + 1;
    int y = floor( random(ny) );
    float hue = random(hueColdHigh-huePointDiff, hueColdHigh);
    coldPoints[i] = new Point(x, y, hue);
    //coldPoints[i] = new Point(x, y, hueWarmLow);
  }  
}

void initializeWarmPoints() {
  for (int i=0; i<nWarmPointsMax; i++) {
    int x = round( random(1.0) ) * (nx-1);
    int y = floor( random(ny) );
    float hue = random(hueWarmLow, hueWarmLow+huePointDiff);
    warmPoints[i] = new Point(x, y, hue);
  }  
}

class Point {
  int x, y;
  float hue;
  Point(int x, int y, float hue) {
    this.x = x;
    this.y = y;
    this.hue = hue;
  }
}

}